Query the journal with SPARQL

The whole journal is a knowledge graph - DCAT 3 / DCAT-AP 3 and the same resources in CIDOC CRM. This page runs SPARQL over it in your browser. Every query is editable; change it, press Run, and see what the graph says.

There is no SPARQL endpoint and no server behind this page. On request your browser loads Python (Pyodide 314.0.7) and rdflib 7.6.0 from this site, about 13 MB, then the four Turtle files listed below with 19,125 triples. Nothing you type leaves your machine.

Graphs: downloads/squirrelpapers.ttl · downloads/squirrelpapers.crm.ttl · vocab/types.ttl · ontology/index.ttl

1. Every published entry, in journal order
2. Entries by type
3. Entries by year
4. Entries per volume and issue
5. People and how often they appear
6. Who wrote with whom
7. Entries by language
8. Conferences and where they took place
9. CIDOC CRM: who created what, and when
10. CIDOC CRM: what was presented where
11. PDF files per volume, with their size

1. Every published entry, in journal order

The table of contents of the whole journal: citation label, title, date and types of each entry. An entry with several types appears once, its types joined with a slash.

SPARQL – Every published entry, in journal order SELECT ?label ?title ?issued (GROUP_CONCAT(?type; separator=" / ") AS ?types) ?entry WHERE { ?entry a bibo:Document ; sqp:citationLabel ?label ; dct:title ?title ; dct:issued ?issued ; prism:volume ?volume ; prism:number ?issue ; sqp:entryNumber ?n . OPTIONAL { ?entry dct:type/skos:notation ?type } # Sort keys as plain integers: volume and issue are strings in PRISM. BIND(xsd:integer(?volume) AS ?v) BIND(xsd:integer(?issue) AS ?i) BIND(xsd:integer(?n) AS ?e) } GROUP BY ?label ?title ?issued ?entry ?v ?i ?e ORDER BY ?v ?i ?e

Run Reset 210 rows when this page was built · entries.rq

2. Entries by type

Counted over the SKOS concepts of the journal's own type vocabulary, with the COAR resource type each one maps to. The same numbers as the type facet on the search page.

SPARQL – Entries by type SELECT ?type ?label ?coar (COUNT(DISTINCT ?entry) AS ?entries) WHERE { ?entry a bibo:Document ; dct:type ?concept . ?concept skos:notation ?type ; skos:prefLabel ?label . FILTER(LANG(?label) = "en") OPTIONAL { ?concept skos:exactMatch|skos:closeMatch ?coar } } GROUP BY ?type ?label ?coar ORDER BY DESC(?entries) ?type

Run Reset 20 rows when this page was built · by-type.rq

3. Entries by year

The year of dct:issued - the date of the talk, poster or publication, not the year of the volume it was gathered into (Volume 1 collects everything up to 2019).

SPARQL – Entries by year SELECT ?year (COUNT(DISTINCT ?entry) AS ?entries) WHERE { ?entry a bibo:Document ; dct:issued ?issued . BIND(SUBSTR(STR(?issued), 1, 4) AS ?year) } GROUP BY ?year ORDER BY DESC(?year)

Run Reset 13 rows when this page was built · by-year.rq

4. Entries per volume and issue

Walks the chain entry → issue → volume through dcat:inSeries, the way DCAT 3 links datasets to dataset series, and counts what hangs on each issue.

SPARQL – Entries per volume and issue SELECT ?volume ?issue ?sigil (COUNT(?entry) AS ?entries) ?issueIri WHERE { ?entry a bibo:Document ; dcat:inSeries ?issueIri . ?issueIri prism:number ?issue ; sqp:sigil ?sigil ; dcat:inSeries ?volumeIri . ?volumeIri prism:volume ?volume . } GROUP BY ?volume ?issue ?sigil ?issueIri ORDER BY DESC(xsd:integer(?volume)) xsd:integer(?issue)

Run Reset 34 rows when this page was built · by-volume.rq

5. People and how often they appear

Authors, contributors and editors of entries, counted per person IRI. A person with an ORCID has an IRI built from it; the owl:sameAs link leads to the ORCID record. The same numbers as the person facet.

SPARQL – People and how often they appear SELECT ?name (COUNT(DISTINCT ?entry) AS ?entries) ?orcid ?person WHERE { ?entry a bibo:Document ; dct:creator|dct:contributor|bibo:editor ?person . ?person foaf:name ?name . OPTIONAL { ?person owl:sameAs ?orcid } } GROUP BY ?person ?name ?orcid ORDER BY DESC(?entries) ?name

Run Reset 106 rows when this page was built · people.rq

6. Who wrote with whom

Pairs of people who share at least two entries as authors. The FILTER on the IRIs keeps each pair once instead of twice.

SPARQL – Who wrote with whom SELECT ?a ?b (COUNT(DISTINCT ?entry) AS ?together) WHERE { ?entry a bibo:Document ; dct:creator ?p1, ?p2 . FILTER(STR(?p1) < STR(?p2)) ?p1 foaf:name ?a . ?p2 foaf:name ?b . } GROUP BY ?a ?b HAVING (COUNT(DISTINCT ?entry) > 1) ORDER BY DESC(?together) ?a ?b

Run Reset 88 rows when this page was built · coauthors.rq

7. Entries by language

dct:language points to the EU language authority. Where the source does not state a language, the build guesses it from the title and marks the entry with sqp:languageGuessed; entries without any language are not counted here.

SPARQL – Entries by language SELECT ?language (COUNT(DISTINCT ?entry) AS ?entries) (SUM(?guess) AS ?guessed) WHERE { ?entry a bibo:Document ; dct:language ?authority . BIND(IF(?authority = <http://publications.europa.eu/resource/authority/language/DEU>, "de", IF(?authority = <http://publications.europa.eu/resource/authority/language/ENG>, "en", STR(?authority))) AS ?language) OPTIONAL { ?entry sqp:languageGuessed ?g } BIND(IF(COALESCE(?g, false), 1, 0) AS ?guess) } GROUP BY ?language ORDER BY DESC(?entries)

Run Reset 2 rows when this page was built · languages.rq

8. Conferences and where they took place

Events with their place as a GeoSPARQL point: the ?wkt column can be pasted into QGIS as delimited text. Online events have no place and are left out.

SPARQL – Conferences and where they took place SELECT ?event ?start ?place ?wkt (COUNT(DISTINCT ?entry) AS ?entries) WHERE { ?entry bibo:presentedAt ?e . ?e rdfs:label ?event ; schema:location ?p . OPTIONAL { ?e schema:startDate ?start } ?p rdfs:label ?place ; geo:hasGeometry/geo:asWKT ?wkt . } GROUP BY ?event ?start ?place ?wkt ORDER BY DESC(?start) ?event

Run Reset 60 rows when this page was built · events-places.rq

9. CIDOC CRM: who created what, and when

The same authorship as in the people query, read from the CRM view instead: an E65 Creation (also LRMoo F28) carried out by persons (P14), with a time-span (P4) whose earliest begin (P82a) gives the date.

SPARQL – CIDOC CRM: who created what, and when SELECT ?title ?person ?begin ?entry WHERE { ?creation a crm:E65_Creation ; crm:P94_has_created ?entry ; crm:P14_carried_out_by ?actor ; crm:P4_has_time-span/crm:P82a_begin_of_the_begin ?begin . ?entry crm:P102_has_title/crm:P190_has_symbolic_content ?title . ?actor rdfs:label ?person . } ORDER BY DESC(?begin) ?title ?person LIMIT 200

Run Reset 200 rows when this page was built · crm-creation.rq

10. CIDOC CRM: what was presented where

An event is an E7 Activity that used the entry (P16) and took place at an E53 Place (P7), whose position is a WKT literal (P168). The PDF of an entry is a CRMdig D1 Digital Object that incorporates it (P165).

SPARQL – CIDOC CRM: what was presented where SELECT ?event ?place ?wkt ?title ?pdf WHERE { ?activity a crm:E7_Activity ; crm:P1_is_identified_by/crm:P190_has_symbolic_content ?event ; crm:P16_used_specific_object ?entry ; crm:P7_took_place_at ?p . ?p crm:P168_place_is_defined_by ?wkt ; rdfs:label ?place . ?entry crm:P102_has_title/crm:P190_has_symbolic_content ?title . OPTIONAL { ?pdf crm:P165_incorporates ?entry ; a crmdig:D1_Digital_Object } } ORDER BY ?event ?title

Run Reset 105 rows when this page was built · crm-presented.rq

11. PDF files per volume, with their size

Every distribution with a byte size, summed per volume. The files stay on Zenodo; the graph records where they are, their media type and an MD5 checksum (SPDX).

SPARQL – PDF files per volume, with their size SELECT ?volume (COUNT(?file) AS ?files) (ROUND(SUM(?bytes) / 10485.76) / 100 AS ?MiB) WHERE { ?entry a bibo:Document ; prism:volume ?volume ; dcat:distribution ?file . ?file dcat:byteSize ?bytes . } GROUP BY ?volume ORDER BY DESC(xsd:integer(?volume))

Run Reset 8 rows when this page was built · pdfs.rq

The queries come from content/queries.yaml in the repository and are run against these graphs whenever the site is built; a query that returns nothing stops the build. The same queries are available as .rq files for any other SPARQL processor.