Das Journal mit SPARQL abfragen

Das ganze Journal ist ein Wissensgraph - DCAT 3 / DCAT-AP 3 und dieselben Ressourcen in CIDOC CRM. Diese Seite führt SPARQL darauf in deinem Browser aus. Jede Abfrage lässt sich bearbeiten; ändern, „Ausführen“ drücken und sehen, was der Graph sagt.

Hinter dieser Seite steht kein SPARQL-Endpunkt und kein Server. Auf Wunsch lädt dein Browser Python (Pyodide 314.0.7) und rdflib 7.6.0 von dieser Seite, etwa 13 MB, danach die vier unten genannten Turtle-Dateien mit 19.125 Tripeln. Nichts, was du eintippst, verlässt deinen Rechner.

Graphen: downloads/squirrelpapers.ttl · downloads/squirrelpapers.crm.ttl · vocab/types.ttl · ontology/index.ttl

1. Alle veröffentlichten Beiträge, in der Reihenfolge des Journals
2. Beiträge nach Typ
3. Beiträge nach Jahr
4. Beiträge je Band und Heft
5. Personen und wie oft sie vorkommen
6. Wer mit wem geschrieben hat
7. Beiträge nach Sprache
8. Konferenzen und wo sie stattfanden
9. CIDOC CRM: wer was wann geschaffen hat
10. CIDOC CRM: was wo vorgestellt wurde
11. PDF-Dateien je Band, mit ihrer Größe

1. Alle veröffentlichten Beiträge, in der Reihenfolge des Journals

Das Inhaltsverzeichnis des ganzen Journals: Zitierlabel, Titel, Datum und Typen jedes Beitrags. Ein Beitrag mit mehreren Typen erscheint einmal, die Typen durch Schrägstrich verbunden.

SPARQL – Alle veröffentlichten Beiträge, in der Reihenfolge des Journals SELECT ?label ?title ?issued (GROUP_CONCAT(?type; separator=" / ") AS ?types) ?entry WHERE { ?entry a bibo:Document ; sqp:citationLabel ?label ; dct:title ?title ; dct:issued ?issued ; prism:volume ?volume ; prism:number ?issue ; sqp:entryNumber ?n . OPTIONAL { ?entry dct:type/skos:notation ?type } # Sort keys as plain integers: volume and issue are strings in PRISM. BIND(xsd:integer(?volume) AS ?v) BIND(xsd:integer(?issue) AS ?i) BIND(xsd:integer(?n) AS ?e) } GROUP BY ?label ?title ?issued ?entry ?v ?i ?e ORDER BY ?v ?i ?e

Ausführen Zurücksetzen 210 Zeilen beim Erstellen dieser Seite · entries.rq

2. Beiträge nach Typ

Gezählt über die SKOS-Konzepte des eigenen Typenvokabulars, mit dem COAR-Ressourcentyp, auf den jedes abgebildet ist. Dieselben Zahlen wie der Typ-Filter der Suchseite. Für deutsche Bezeichnungen "en" durch "de" ersetzen.

SPARQL – Beiträge nach Typ SELECT ?type ?label ?coar (COUNT(DISTINCT ?entry) AS ?entries) WHERE { ?entry a bibo:Document ; dct:type ?concept . ?concept skos:notation ?type ; skos:prefLabel ?label . FILTER(LANG(?label) = "en") OPTIONAL { ?concept skos:exactMatch|skos:closeMatch ?coar } } GROUP BY ?type ?label ?coar ORDER BY DESC(?entries) ?type

Ausführen Zurücksetzen 20 Zeilen beim Erstellen dieser Seite · by-type.rq

3. Beiträge nach Jahr

Das Jahr aus dct:issued - das Datum von Vortrag, Poster oder Veröffentlichung, nicht das Jahr des Bandes, in dem der Beitrag steht (Band 1 sammelt alles bis 2019).

SPARQL – Beiträge nach Jahr SELECT ?year (COUNT(DISTINCT ?entry) AS ?entries) WHERE { ?entry a bibo:Document ; dct:issued ?issued . BIND(SUBSTR(STR(?issued), 1, 4) AS ?year) } GROUP BY ?year ORDER BY DESC(?year)

Ausführen Zurücksetzen 13 Zeilen beim Erstellen dieser Seite · by-year.rq

4. Beiträge je Band und Heft

Geht die Kette Beitrag → Heft → Band über dcat:inSeries, wie DCAT 3 Datensätze mit Datensatzserien verbindet, und zählt, was an jedem Heft hängt.

SPARQL – Beiträge je Band und Heft SELECT ?volume ?issue ?sigil (COUNT(?entry) AS ?entries) ?issueIri WHERE { ?entry a bibo:Document ; dcat:inSeries ?issueIri . ?issueIri prism:number ?issue ; sqp:sigil ?sigil ; dcat:inSeries ?volumeIri . ?volumeIri prism:volume ?volume . } GROUP BY ?volume ?issue ?sigil ?issueIri ORDER BY DESC(xsd:integer(?volume)) xsd:integer(?issue)

Ausführen Zurücksetzen 34 Zeilen beim Erstellen dieser Seite · by-volume.rq

5. Personen und wie oft sie vorkommen

Autorinnen und Autoren, Mitwirkende und Herausgebende von Beiträgen, gezählt je Personen-IRI. Wer eine ORCID hat, bekommt eine daraus gebildete IRI; owl:sameAs führt zum ORCID-Eintrag. Dieselben Zahlen wie der Personen-Filter.

SPARQL – Personen und wie oft sie vorkommen SELECT ?name (COUNT(DISTINCT ?entry) AS ?entries) ?orcid ?person WHERE { ?entry a bibo:Document ; dct:creator|dct:contributor|bibo:editor ?person . ?person foaf:name ?name . OPTIONAL { ?person owl:sameAs ?orcid } } GROUP BY ?person ?name ?orcid ORDER BY DESC(?entries) ?name

Ausführen Zurücksetzen 106 Zeilen beim Erstellen dieser Seite · people.rq

6. Wer mit wem geschrieben hat

Paare von Personen mit mindestens zwei gemeinsamen Beiträgen als Autor:innen. Der FILTER auf die IRIs zählt jedes Paar einmal statt zweimal.

SPARQL – Wer mit wem geschrieben hat SELECT ?a ?b (COUNT(DISTINCT ?entry) AS ?together) WHERE { ?entry a bibo:Document ; dct:creator ?p1, ?p2 . FILTER(STR(?p1) < STR(?p2)) ?p1 foaf:name ?a . ?p2 foaf:name ?b . } GROUP BY ?a ?b HAVING (COUNT(DISTINCT ?entry) > 1) ORDER BY DESC(?together) ?a ?b

Ausführen Zurücksetzen 88 Zeilen beim Erstellen dieser Seite · coauthors.rq

7. Beiträge nach Sprache

dct:language verweist auf die Sprachen-Normdatei der EU. Wo die Quelle keine Sprache nennt, schätzt der Build sie aus dem Titel und markiert den Beitrag mit sqp:languageGuessed; Beiträge ganz ohne Sprache zählen hier nicht.

SPARQL – Beiträge nach Sprache SELECT ?language (COUNT(DISTINCT ?entry) AS ?entries) (SUM(?guess) AS ?guessed) WHERE { ?entry a bibo:Document ; dct:language ?authority . BIND(IF(?authority = <http://publications.europa.eu/resource/authority/language/DEU>, "de", IF(?authority = <http://publications.europa.eu/resource/authority/language/ENG>, "en", STR(?authority))) AS ?language) OPTIONAL { ?entry sqp:languageGuessed ?g } BIND(IF(COALESCE(?g, false), 1, 0) AS ?guess) } GROUP BY ?language ORDER BY DESC(?entries)

Ausführen Zurücksetzen 2 Zeilen beim Erstellen dieser Seite · languages.rq

8. Konferenzen und wo sie stattfanden

Veranstaltungen mit ihrem Ort als GeoSPARQL-Punkt: Die Spalte ?wkt lässt sich als Textdatei mit Trennzeichen in QGIS laden. Online-Veranstaltungen haben keinen Ort und fehlen hier.

SPARQL – Konferenzen und wo sie stattfanden SELECT ?event ?start ?place ?wkt (COUNT(DISTINCT ?entry) AS ?entries) WHERE { ?entry bibo:presentedAt ?e . ?e rdfs:label ?event ; schema:location ?p . OPTIONAL { ?e schema:startDate ?start } ?p rdfs:label ?place ; geo:hasGeometry/geo:asWKT ?wkt . } GROUP BY ?event ?start ?place ?wkt ORDER BY DESC(?start) ?event

Ausführen Zurücksetzen 60 Zeilen beim Erstellen dieser Seite · events-places.rq

9. CIDOC CRM: wer was wann geschaffen hat

Dieselbe Autorschaft wie in der Personen-Abfrage, diesmal aus der CRM-Sicht gelesen: eine E65-Schöpfung (zugleich LRMoo F28), ausgeführt von Personen (P14), mit einer Zeitspanne (P4), deren frühester Beginn (P82a) das Datum liefert.

SPARQL – CIDOC CRM: wer was wann geschaffen hat SELECT ?title ?person ?begin ?entry WHERE { ?creation a crm:E65_Creation ; crm:P94_has_created ?entry ; crm:P14_carried_out_by ?actor ; crm:P4_has_time-span/crm:P82a_begin_of_the_begin ?begin . ?entry crm:P102_has_title/crm:P190_has_symbolic_content ?title . ?actor rdfs:label ?person . } ORDER BY DESC(?begin) ?title ?person LIMIT 200

Ausführen Zurücksetzen 200 Zeilen beim Erstellen dieser Seite · crm-creation.rq

10. CIDOC CRM: was wo vorgestellt wurde

Eine Veranstaltung ist eine E7-Aktivität, die den Beitrag benutzt hat (P16) und an einem E53-Ort stattfand (P7), dessen Lage ein WKT-Literal ist (P168). Das PDF eines Beitrags ist ein CRMdig-D1-Digitalobjekt, das ihn enthält (P165).

SPARQL – CIDOC CRM: was wo vorgestellt wurde SELECT ?event ?place ?wkt ?title ?pdf WHERE { ?activity a crm:E7_Activity ; crm:P1_is_identified_by/crm:P190_has_symbolic_content ?event ; crm:P16_used_specific_object ?entry ; crm:P7_took_place_at ?p . ?p crm:P168_place_is_defined_by ?wkt ; rdfs:label ?place . ?entry crm:P102_has_title/crm:P190_has_symbolic_content ?title . OPTIONAL { ?pdf crm:P165_incorporates ?entry ; a crmdig:D1_Digital_Object } } ORDER BY ?event ?title

Ausführen Zurücksetzen 105 Zeilen beim Erstellen dieser Seite · crm-presented.rq

11. PDF-Dateien je Band, mit ihrer Größe

Jede Distribution mit Bytegröße, je Band summiert. Die Dateien bleiben auf Zenodo; der Graph hält fest, wo sie liegen, ihren Medientyp und eine MD5-Prüfsumme (SPDX).

SPARQL – PDF-Dateien je Band, mit ihrer Größe SELECT ?volume (COUNT(?file) AS ?files) (ROUND(SUM(?bytes) / 10485.76) / 100 AS ?MiB) WHERE { ?entry a bibo:Document ; prism:volume ?volume ; dcat:distribution ?file . ?file dcat:byteSize ?bytes . } GROUP BY ?volume ORDER BY DESC(xsd:integer(?volume))

Ausführen Zurücksetzen 8 Zeilen beim Erstellen dieser Seite · pdfs.rq

Die Abfragen stammen aus content/queries.yaml im Repository und werden bei jedem Build gegen diese Graphen ausgeführt; eine Abfrage ohne Ergebnis hält den Build an. Dieselben Abfragen gibt es als .rq-Dateien für jeden anderen SPARQL-Prozessor.